***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 22, 2025                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PZ1AL24B-AU  A K 
.param
+vc0 = 1.646e-10	 vc1 = 6.016e-12         vc2 = 0.1	        vc3 = 5.313e-12	   vc4 = 1.465e-1
+tc1 = 1.958e-2		 tc2 = 8.026e-3		 tc3 = 9.058e-3		tc4 = 3.586e-2
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A A1 zener
g1 A1 A value = {irexp(v(A1,A))}
v1 A1 K1 0
e1 K1 K value = {rbv(i(v1))}
.func rbv(i) {2.652e-1*min(i,0)}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 5.296e-15	   n = 1.037              rs = 1.688e-2
+ibv = 2.5e-2		 nbv = 1.000	          bv = 24
+ikf = 1.927
***** capacitance parameter *****
+cjo = 1.730e-10	   m = 3.127e-1		  vj = 5.561e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.120		 xti = 3
+trs1 = 6.886e-4         tikf= 9.8e-3       
+tbv1 = 8.555e-4
.ends PZ1AL24B-AU
*$
